Eigenvalues and Eigenvectors of a Hermitian Matrix in Packed Storage (Simple Driver)

Calling Sequence

CALL ZHPEV	(JOBZ, UPLO, N, ZA, DW, ZZ, LDZ, ZWORK, DWORK2, INFO)
CALL CHPEV	(JOBZ, UPLO, N, CA, SW, CZ, LDZ, CWORK, SWORK2, INFO)
void zhpev	(char jobz, char uplo, int n, doublecomplex *za, double *dw, doublecomplex *zz, int ldz, int *info)
void chpev	(char jobz, char uplo, int n, complex *ca, float *sw, complex *cz, int ldz, int *info)

Arguments

JOBZ	Indicates whether to compute eigenvalues only or to compute both eigenvalues and eigenvectors. The legal values for JOBZ are listed below. Any values not listed below are illegal.
	'N' or 'n'	Compute eigenvalues only.
	'V' or 'v'	Compute both eigenvalues and eigenvectors.
UPLO	Indicates whether xA contains the upper or lower triangle of the matrix. The legal values for UPLO are listed below. Any values not listed below are illegal.
	'U' or 'u'	xA contains the upper triangle.
	'L' or 'l'	xA contains the lower triangle.
N	Order of the matrix A. N 0.
xA	On entry, the upper or lower triangle of the matrix A. The dimension of xA is (N × N + N) / 2. On exit, A is overwritten.
xW	On exit, the N eigenvalues in ascending order.
xZ	On exit, if JOBZ = 'V' or 'v' then Z contains the orthonormal eigenvectors. If JOBZ = 'N' or 'n' then Z is not used.
LDZ	Leading dimension of the array Z as specified in a dimension or type statement. LDZ 1. If JOBZ = 'V' or 'v' then LDZ max(1, N).
xWORK	Scratch array with a dimension of max(1, 2 × N - 1).
xWORK2	Scratch array with a dimension of max(1, 3 × N - 2).
INFO	On exit:
	INFO = 0	Subroutine completed normally.
	INFO < 0	The ith argument, where i = |INFO|, had an illegal value.
	INFO > 0	Convergence failure.

Sample Program

PROGRAM TEST

IMPLICIT NONE

C

INTEGER LDEVAL, LDEVEC, LDWORK, LDWRK2, LENGTA, N

PARAMETER (N = 3)

PARAMETER (LDEVAL = N)

PARAMETER (LDEVEC = N)

PARAMETER (LDWORK = 2 * N - 1)

PARAMETER (LDWRK2 = 3 * N - 2)

PARAMETER (LENGTA = (N * N + N) / 2)

C

DOUBLE PRECISION EVALS(LDEVAL), WORK2(LDWRK2)

COMPLEX*16 A(LENGTA), EVECS(LDEVEC,N), WORK(LDWORK)

INTEGER ICOL, INFO, IROW

C

EXTERNAL ZHPEV

INTRINSIC ABS, CONJG

C

C Initialize the array A to store the coefficient array A

C shown below.

C

C 4 4-4i 0

C A = 4+4i 4 4-4i

C 0 4+4i 4

C

DATA A / (4.0D0,0.0D0), (4.0D0,-4.0D0), (4.0D0,0.0D0),

$ (0.0D0,0.0D0), (4.0D0,-4.0D0), (4.0D0,0.0D0) /

C

C Print the initial value of A.

C

PRINT 1000

PRINT 1010, A(1), A(2), A(4)

PRINT 1010, CONJG(A(2)), A(3), A(5)

PRINT 1010, CONJG(A(4)), CONJG(A(5)), A(6)

C

C Compute the eigenvalues and eigenvectors.

C

CALL ZHPEV ('VALUES AND VECTORS, EIGEN',

$ 'UPPER TRIANGLE OF A STORED', N, A, EVALS,

$ EVECS, LDEVEC, WORK, WORK2, INFO)

IF (INFO .LT. 0) THEN

PRINT 1020, ABS(INFO)

STOP 1

ELSE IF (INFO .GT. 0) THEN

PRINT 1030, INFO

STOP 2

END IF

C

C Print the eigenvalues and eigenvectors.

C

PRINT 1040

DO 200, IROW = 1, N

PRINT 1050, EVALS(IROW), (EVECS(IROW,ICOL), ICOL = 1, N)

200 CONTINUE

C

1000 FORMAT (1X, 'A:')

1010 FORMAT (1X, 10(: 2X, '(', F5.1, ',', F5.1, ')'))

1020 FORMAT (1X, 'Illegal argument to ZHPEV, argument #', I2)

1030 FORMAT (1X, 'Convergence failure, INFO = ', I2)

1040 FORMAT (/1X, 'Eigenvalue', 16X, 'Eigenvector**T')

1050 FORMAT (1X, F8.3, 6X, '[', 3('(', F4.1, ',', F4.1, ') '),

$ ']')

C

END

Sample Output

A:

( 4.0, 0.0) ( 4.0, -4.0) ( 0.0, 0.0)

( 4.0, 4.0) ( 4.0, 0.0) ( 4.0, -4.0)

( 0.0, 0.0) ( 4.0, 4.0) ( 4.0, 0.0)

Eigenvalue Eigenvector**T

-4.000 [( 0.0, 0.5) ( 0.0, 0.7) ( 0.0, 0.5) ]

4.000 [( 0.5,-0.5) ( 0.0, 0.0) (-0.5, 0.5) ]

12.000 [(-0.5, 0.0) ( 0.7, 0.0) (-0.5, 0.0) ]